Mengatasi ukuran file Excel yang tiba-tiba membesar dibatas kewajaran

Anda bingung dengan file Microsoft Excel anda yang tiba-tiba besar?

Microsoft Excel adalah salah satu aplikasi pengolah angka yang dapat membantu untuk kebutuhan pengelolaan data yang memerlukan rumus dalam pengelolaannya seperti laporan-laporan harian dengan beberapa tabel data yang akan dihitung.
Namun kita sering dikagetkan dengan ukuran file yang besarnya tidak wajar, hal tersebut dikarenakan kita melakukan formating cell yang tidak seharusnya. Untuk itu kita bisa mengatasinya dengan melihat sheet mana yang ukurannya terlalu besar, diikuti dengan melakukan claer format pada cell yang tidak perlu di format.
Dengan bantuan sediktit script dibawah ini, kita bisa mengetahui ukuran sheet mana yang terlalu besar.

Klik kanan pada salah satu nama sheet, kemudian klik View Code

    
Sub CekUkuran()
    Dim wks As Worksheet
    Dim c As Range
    Dim sFullFile As String
    Dim sReport As String
    sReport = "Hasil"
    sFullFile = ThisWorkbook.Path & _
    Application.PathSeparator & "hapus.xls"
    On Error Resume Next
    Set wks = Worksheets(sReport)
    If wks Is Nothing Then
        With ThisWorkbook.Worksheets.Add(Before:=Worksheets(1))
            .Name = sReport
            .Range("A1").Value = "Nama Sheet"
            .Range("B1").Value = "Ukuran"
        End With
    End If
    On Error GoTo 0
    With ThisWorkbook.Worksheets(sReport)
        .Select
        .Range("A1").CurrentRegion.Offset(1, 0).ClearContents
        Set c = .Range("A2")
    End With
    Application.ScreenUpdating = False
    For Each wks In ActiveWorkbook.Worksheets
        If wks.Name <> sReport Then
            wks.Copy
            Application.DisplayAlerts = False
            ActiveWorkbook.SaveAs sFullFile
            ActiveWorkbook.Close SaveChanges:=False
            Application.DisplayAlerts = True
            c.Offset(0, 0).Value = wks.Name
            c.Offset(0, 1).Value = FileLen(sFullFile)
            Set c = c.Offset(1, 0)
            Kill sFullFile
        End If
    Next wks
    Application.ScreenUpdating = True
End Sub
    

Paste kode diatas kemudian klik Run dilanjutkan dengan klik Run Sub/UserForm F5 atau juga bisa langsung menekan tombol F5 pada keyboard anda

Download demo DISINI

Terima kasih telah membaca materi ini yang berjudul Mengatasi ukuran file Excel yang tiba-tiba membesar dibatas kewajaran dan jangan lupa bagikan melalui sosial media anda dengan klik icon yang berada dibawah judul materi ini.

Kritik dan saran silahkan kirim ke WhatsApp, Instagram atau Facebook.